mirror of
https://github.com/openfoodfoundation/openfoodnetwork
synced 2026-01-26 20:56:48 +00:00
42 lines
1.5 KiB
CoffeeScript
42 lines
1.5 KiB
CoffeeScript
Darkswarm.factory 'StripeElements', ($rootScope, Loading, RailsFlashLoader) ->
|
|
new class StripeElements
|
|
# TODO: add locale here for translations of error messages etc. from Stripe
|
|
|
|
# These are both set from the StripeElements directive
|
|
stripe: null
|
|
card: null
|
|
|
|
# New Stripe Elements method
|
|
requestToken: (secrets, submit, loading_message = t("processing_payment")) ->
|
|
return unless @stripe? && @card?
|
|
|
|
Loading.message = loading_message
|
|
cardData = @makeCardData(secrets)
|
|
|
|
@stripe.createToken(@card, cardData).then (response) =>
|
|
if(response.error)
|
|
Loading.clear()
|
|
RailsFlashLoader.loadFlash({error: t("error") + ": #{response.error.message}"})
|
|
else
|
|
secrets.token = response.token.id
|
|
secrets.cc_type = @mapCC(response.token.card.brand)
|
|
secrets.card = response.token.card
|
|
submit()
|
|
|
|
# Maps the brand returned by Stripe to that required by activemerchant
|
|
mapCC: (ccType) ->
|
|
switch ccType
|
|
when 'MasterCard' then return 'master'
|
|
when 'Visa' then return 'visa'
|
|
when 'American Express' then return 'american_express'
|
|
when 'Discover' then return 'discover'
|
|
when 'JCB' then return 'jcb'
|
|
when 'Diners Club' then return 'diners_club'
|
|
|
|
# It doesn't matter if any of these are nil, all are optional.
|
|
makeCardData: (secrets) ->
|
|
{'name': secrets.name,
|
|
'address1': secrets.address1,
|
|
'city': secrets.city,
|
|
'zipcode': secrets.zipcode}
|